1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
|
-- Programmed by Jedidiah Barber
-- Released into the public domain
with
Ada.Strings.Fixed,
Ada.Strings.Unbounded,
Ada.Unchecked_Deallocation,
Interfaces.C.Strings;
package body FLTK.Images.Pixmaps is
------------------------
-- Functions From C --
------------------------
function new_fl_pixmap
(D : in Storage.Integer_Address)
return Storage.Integer_Address;
pragma Import (C, new_fl_pixmap, "new_fl_pixmap");
pragma Inline (new_fl_pixmap);
procedure free_fl_pixmap
(I : in Storage.Integer_Address);
pragma Import (C, free_fl_pixmap, "free_fl_pixmap");
pragma Inline (free_fl_pixmap);
function fl_pixmap_copy
(I : in Storage.Integer_Address;
W, H : in Interfaces.C.int)
return Storage.Integer_Address;
pragma Import (C, fl_pixmap_copy, "fl_pixmap_copy");
pragma Inline (fl_pixmap_copy);
function fl_pixmap_copy2
(I : in Storage.Integer_Address)
return Storage.Integer_Address;
pragma Import (C, fl_pixmap_copy2, "fl_pixmap_copy2");
pragma Inline (fl_pixmap_copy2);
procedure fl_pixmap_color_average
(I : in Storage.Integer_Address;
C : in Interfaces.C.int;
B : in Interfaces.C.C_float);
pragma Import (C, fl_pixmap_color_average, "fl_pixmap_color_average");
pragma Inline (fl_pixmap_color_average);
procedure fl_pixmap_desaturate
(I : in Storage.Integer_Address);
pragma Import (C, fl_pixmap_desaturate, "fl_pixmap_desaturate");
pragma Inline (fl_pixmap_desaturate);
procedure fl_pixmap_uncache
(I : in Storage.Integer_Address);
pragma Import (C, fl_pixmap_uncache, "fl_pixmap_uncache");
pragma Inline (fl_pixmap_uncache);
procedure fl_pixmap_draw2
(I : in Storage.Integer_Address;
X, Y : in Interfaces.C.int);
pragma Import (C, fl_pixmap_draw2, "fl_pixmap_draw2");
pragma Inline (fl_pixmap_draw2);
procedure fl_pixmap_draw
(I : in Storage.Integer_Address;
X, Y, W, H, CX, CY : in Interfaces.C.int);
pragma Import (C, fl_pixmap_draw, "fl_pixmap_draw");
pragma Inline (fl_pixmap_draw);
-------------------
-- Destructors --
-------------------
type chars_ptr_array_access is access all Interfaces.C.Strings.chars_ptr_array;
procedure Free is new Ada.Unchecked_Deallocation
(Interfaces.C.Strings.chars_ptr_array, chars_ptr_array_access);
overriding procedure Finalize
(This : in out Pixmap) is
begin
if This.Void_Ptr /= Null_Pointer and This.Needs_Dealloc then
if This.Loose_Ptr /= null then
for Item of This.Loose_Ptr.all loop
Interfaces.C.Strings.Free (Item);
end loop;
Free (This.Loose_Ptr);
end if;
free_fl_pixmap (This.Void_Ptr);
This.Void_Ptr := Null_Pointer;
end if;
end Finalize;
--------------------
-- Constructors --
--------------------
package body Forge is
function To_Coltype
(Value : in Color_Kind)
return Character is
begin
case Value is
when Colorful => return 'c';
when Monochrome => return 'm';
when Greyscale => return 'g';
when Symbolic => return 's';
end case;
end To_Coltype;
function Create
(Values : in Header;
Colors : in Color_Definition_Array;
Pixels : in Pixmap_Data)
return Pixmap
is
use Interfaces.C.Strings;
C_Data : access chars_ptr_array := new chars_ptr_array
(1 .. Interfaces.C.size_t (1 + Colors'Length + Pixels'Length (1)));
begin
-- Header values line
C_Data (1) := New_String (Ada.Strings.Fixed.Trim
((Positive'Image (Values.Width) & Positive'Image (Values.Height) &
Positive'Image (Values.Colors) & Positive'Image (Values.Per_Pixel)),
Ada.Strings.Left));
-- Color definition lines
for Place in 1 .. Colors'Length loop
C_Data (Interfaces.C.size_t (Place + 1)) := New_String
(Ada.Strings.Unbounded.To_String (Colors (Colors'First + Place - 1).Name) & " " &
To_Coltype (Colors (Colors'First + Place - 1).Kind) & " " &
Ada.Strings.Unbounded.To_String (Colors (Colors'First + Place - 1).Value));
end loop;
-- Pixel data lines
for Place in 1 .. Pixels'Length (1) loop
declare
Line : String (1 .. Pixels'Length (2));
for Line'Address use Pixels (Pixels'First (1) + Place - 1, 1)'Address;
pragma Import (Ada, Line);
begin
C_Data (Interfaces.C.size_t (Place + 1 + Colors'Length)) := New_String (Line);
end;
end loop;
-- Pass it all off to C++ to actually create the cursed thing
return This : Pixmap do
This.Void_Ptr := new_fl_pixmap (Storage.To_Integer (C_Data (C_Data'First)'Address));
This.Loose_Ptr := C_Data; -- Much easier to save this for later
end return;
end Create;
end Forge;
-----------------------
-- API Subprograms --
-----------------------
-- Copying --
function Copy
(This : in Pixmap;
Width, Height : in Natural)
return Pixmap'Class is
begin
return Copied : Pixmap do
Copied.Void_Ptr := fl_pixmap_copy
(This.Void_Ptr,
Interfaces.C.int (Width),
Interfaces.C.int (Height));
end return;
end Copy;
function Copy
(This : in Pixmap)
return Pixmap'Class is
begin
return Copied : Pixmap do
Copied.Void_Ptr := fl_pixmap_copy2 (This.Void_Ptr);
end return;
end Copy;
-- Colors --
procedure Color_Average
(This : in out Pixmap;
Col : in Color;
Amount : in Blend) is
begin
fl_pixmap_color_average
(This.Void_Ptr,
Interfaces.C.int (Col),
Interfaces.C.C_float (Amount));
end Color_Average;
procedure Desaturate
(This : in out Pixmap) is
begin
fl_pixmap_desaturate (This.Void_Ptr);
end Desaturate;
-- Activity --
procedure Uncache
(This : in out Pixmap) is
begin
fl_pixmap_uncache (This.Void_Ptr);
end Uncache;
-- Drawing --
procedure Draw
(This : in Pixmap;
X, Y : in Integer) is
begin
fl_pixmap_draw2
(This.Void_Ptr,
Interfaces.C.int (X),
Interfaces.C.int (Y));
end Draw;
procedure Draw
(This : in Pixmap;
X, Y, W, H : in Integer;
Clip_X, Clip_Y : in Integer := 0) is
begin
fl_pixmap_draw
(This.Void_Ptr,
Interfaces.C.int (X),
Interfaces.C.int (Y),
Interfaces.C.int (W),
Interfaces.C.int (H),
Interfaces.C.int (Clip_X),
Interfaces.C.int (Clip_Y));
end Draw;
end FLTK.Images.Pixmaps;
|
