path: root/test/ratnest-tests.adb

with

    Ada.Characters.Latin_1,
    Ada.Strings.Maps,
    Packrat.Lexer.Combinators,
    Packrat.Util;


package body Ratnest.Tests is


    package Latin renames Ada.Characters.Latin_1;
    package Strmaps renames Ada.Strings.Maps;
    package PE renames Packrat.Errors;
    package PU renames Packrat.Util;





    package body Errors is


        function Valid_Message_Check
            return Test_Result is
        begin
            if  PE.Valid_Message ("abcde") or PE.Valid_Message ("sSYM") or
                PE.Valid_Message ("sSYMp") or PE.Valid_Message ("p345") or
                PE.Valid_Message ("pOne") or PE.Valid_Message ("sSYMp1sNEXT") or
                PE.Valid_Message ("sSYMp1.2") or PE.Valid_Message ("sABcDp12") or
                not PE.Valid_Message ("sSYMp0") or not PE.Valid_Message ("sAp12") or
                not PE.Valid_Message ("sNAMEp34sSYMp02") or not PE.Valid_Message ("") or
                not PE.Valid_Message ("sA_Bp3") or not PE.Valid_Message ("sAp1sAp1")
            then
                return Fail;
            end if;
            return Pass;
        end Valid_Message_Check;


        function Valid_Identifier_Check
            return Test_Result
        is
            Pass_Array : PE.Error_Info_Array :=
                ((+"A", 1), (+"ABC", 2), (+"AB_CD", 3), (+"A_B_CD", 4));
            Fail_Array : PE.Error_Info_Array :=
                ((+"_", 1), (+"_A", 2), (+"A_", 3), (+"A__B", 4), (+"A%B", 3));
        begin
            for EI of Pass_Array loop
                if  not PE.Valid_Identifier (EI.Symbol) or
                    not PE.Valid_Identifier (-EI.Symbol)
                then
                    return Fail;
                end if;
            end loop;
            for EI of Fail_Array loop
                if  PE.Valid_Identifier (EI.Symbol) or
                    PE.Valid_Identifier (-EI.Symbol)
                then
                    return Fail;
                end if;
            end loop;
            if  not PE.Valid_Identifier_Array (Pass_Array) or
                PE.Valid_Identifier_Array (Fail_Array)
            then
                return Fail;
            end if;
            return Pass;
        end Valid_Identifier_Check;


        function Join_Check
            return Test_Result
        is
            Array_1 : PE.Error_Info_Array := ((+"A", 1), (+"B", 2));
            Msg_1 : PE.Error_Message := PE.Encode_Array (Array_1);

            Array_2 : PE.Error_Info_Array := ((+"C", 3), (+"D", 4));
            Msg_2 : PE.Error_Message := PE.Encode_Array (Array_2);

            Msg_3 : PE.Error_Message := PE.Join (Msg_1, Msg_2);

            Array_4 : PE.Error_Info_Array := ((+"A", 1), (+"B", 2), (+"C", 3), (+"D", 4));
            Msg_4 : PE.Error_Message := PE.Encode_Array (Array_4);

            Array_5 : PE.Error_Info_Array := ((+"A", 1), (+"B", 4));
            Msg_5 : PE.Error_Message := PE.Encode_Array (Array_5);

            Array_6 : PE.Error_Info_Array := ((+"A", 1), (+"C", 3));
            Msg_6 : PE.Error_Message := PE.Encode_Array (Array_6);

            Msg_7 : PE.Error_Message := PE.Join (Msg_5, Msg_6);

            Array_8 : PE.Error_Info_Array := ((+"A", 1), (+"B", 4), (+"C", 3));
            Msg_8 : PE.Error_Message := PE.Encode_Array (Array_8);
        begin
            if Msg_3 /= Msg_4 or Msg_7 /= Msg_8 then
                return Fail;
            end if;
            return Pass;
        end Join_Check;


        function Encode_1_Check
            return Test_Result is
        begin
            --  Encode with a String and a Natural
            if PE.Encode ("ABC", 15) /= "sABCp15" then
                return Fail;
            end if;
            return Pass;
        end Encode_1_Check;


        function Encode_2_Check
            return Test_Result is
        begin
            --  Encode with an Unbounded_String and a Natural
            if PE.Encode (+"ABC", 15) /= "sABCp15" then
                return Fail;
            end if;
            return Pass;
        end Encode_2_Check;


        function Encode_3_Check
            return Test_Result is
        begin
            --  Encode with an Error_Info
            if PE.Encode ((+"ABC", 15)) /= "sABCp15" then
                return Fail;
            end if;
            return Pass;
        end Encode_3_Check;


        function Encode_4_Check
            return Test_Result is
        begin
            --  Encode with an Error_Info_Array
            if  PE.Encode_Array (((+"A", 3), (+"BC", 2), (+"ABC", 1), (+"B", 4))) /=
                "sAp3sBCp2sABCp1sBp4"
            then
                return Fail;
            end if;
            return Pass;
        end Encode_4_Check;


        function Decode_Check
            return Test_Result
        is
            use type PE.Error_Info_Array;
        begin
            if PE.Decode ("sAp1sBp3sCp10sDEFp456") /=
                ((+"A", 1), (+"B", 3), (+"C", 10), (+"DEF", 456))
            then
                return Fail;
            end if;
            return Pass;
        end Decode_Check;


    end Errors;





    package body Tokens is


        type My_Labels is (One, Two, Three);
        package My_Tokens is new Packrat.Tokens (My_Labels, Character, String);


        function Adjust_Check
            return Test_Result
        is
            A : My_Tokens.Token;
        begin
            declare
                B : My_Tokens.Token := My_Tokens.Create (One, 1, 3, "abc");
            begin
                A := B;
            end;
            if not A.Initialized or else A.Value /= "abc" then
                return Fail;
            end if;
            return Pass;
        end Adjust_Check;


        function Equals_Check
            return Test_Result
        is
            use type My_Tokens.Token;
            A : My_Tokens.Token := My_Tokens.Create (One, 1, 3, "abc");
            B : My_Tokens.Token := My_Tokens.Create (One, 1, 3, "abc");
        begin
            if A /= B then
                return Fail;
            end if;
            return Pass;
        end Equals_Check;


        function Store_Check
            return Test_Result
        is
            T : My_Tokens.Token := My_Tokens.Create (One, 1, 3, "abc");
        begin
            if  not T.Initialized or else
                T.Label /= One or else
                T.Start /= 1 or else T.Finish /= 3 or else
                T.Value /= "abc"
            then
                return Fail;
            end if;
            return Pass;
        end Store_Check;


    end Tokens;





    package body Lexer is


        type My_Labels is (One, Two, Three);


        package String_Tokens is new Packrat.Tokens (My_Labels, Character, String);
        package Slexy is new Packrat.Lexer (My_Labels, Character, String, String_Tokens);
        package Strombo is new Slexy.Combinators;


        use type Slexy.Combinator_Result;





        function Join_Check
            return Test_Result
        is
            One   : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "a");
            Two   : Slexy.Combinator_Result :=
                Slexy.Create_Result (2, Packrat.Success, "bc");
            Three : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Success, "abc");

            Four  : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Failure, "xyz");
            Five  : Slexy.Combinator_Result :=
                Slexy.Create_Result (4, Packrat.Failure, "axyz");

            Six   : Slexy.Combinator_Result :=
                Slexy.Create_Result (4, Packrat.Needs_More, "cd");
            Seven : Slexy.Combinator_Result :=
                Slexy.Create_Result (5, Packrat.Needs_More, "acd");

            Eight : Slexy.Combinator_Result :=
                Slexy.Create_Result (4, Packrat.Failure, "cd");

            Nine  : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Optional_More, "abc");
            Ten   : Slexy.Combinator_Result :=
                Slexy.Create_Result (5, Packrat.Success, "abcbc");
        begin
            if  One.Join (Two) /= Three or One.Join (Four) /= Five or
                One.Join (Six) /= Seven or Four.Join (Six) /= Four or
                Five.Join (Two) /= Five or Six.Join (Three) /= Eight or
                Slexy.Empty_Fail.Join (One) /= Slexy.Empty_Fail or
                Nine.Join (Two) /= Ten
            then
                return Fail;
            end if;
            return Pass;
        end Join_Check;


        function Equals_Check
            return Test_Result
        is
            One : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Success, "abc");
            Two : Slexy.Combinator_Result :=
                Slexy.Create_Result (0, Packrat.Failure, "");
        begin
            if One = Two or Two /= Slexy.Empty_Fail then
                return Fail;
            end if;
            return Pass;
        end Equals_Check;





        function Sequence_Check
            return Test_Result
        is
            function Match_A is new Strombo.Match ('a');
            function Match_B is new Strombo.Match ('b');
            function Match_C is new Strombo.Match ('c');
            function Seq_Abc is new Strombo.Sequence
              ((Match_A'Unrestricted_Access,
                Match_B'Unrestricted_Access,
                Match_C'Unrestricted_Access));

            Test_Str : String := "aababcabcab";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Failure, "a");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (2, Packrat.Needs_More, "ab");
            Result3 : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Success, "abc");
            Result4 : Slexy.Combinator_Result := Slexy.Empty_Fail;
            Result5 : Slexy.Combinator_Result :=
                Slexy.Create_Result (2, Packrat.Failure, "ab");
        begin
            if  Seq_Abc (Test_Str, 1) /= Result1 or Seq_Abc (Test_Str, 2) /= Result5 or
                Seq_Abc (Test_Str, 4) /= Result3 or Seq_Abc (Test_Str, 10) /= Result2 or
                Seq_Abc (Test_Str, 3) /= Result4 or
                Seq_Abc (Test_Str, Test_Str'Last + 5) /= Result4
            then
                return Fail;
            end if;
            return Pass;
        end Sequence_Check;


        function Count_Check
            return Test_Result
        is
            function Match_A is new Strombo.Match ('a');
            function Match_B is new Strombo.Match ('b');
            function Count_2A is new Strombo.Count (Match_A, 2);
            function Count_3B is new Strombo.Count (Match_B, 3);

            Test_Str : String := "abaabbaaabbbaaaabbbb";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Failure, "a");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (2, Packrat.Success, "aa");
            Result3 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Failure, "b");
            Result4 : Slexy.Combinator_Result :=
                Slexy.Create_Result (2, Packrat.Needs_More, "bb");
            Result5 : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Success, "bbb");
            Result6 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  Count_2A (Test_Str, 1) /= Result1 or Count_2A (Test_Str, 3) /= Result2 or
                Count_3B (Test_Str, 2) /= Result3 or Count_3B (Test_Str, 19) /= Result4 or
                Count_3B (Test_Str, 10) /= Result5 or Count_3B (Test_Str, 1) /= Result6 or
                Count_2A (Test_Str, 2) /= Result6 or
                Count_2A (Test_Str, Test_Str'Last + 5) /= Result6
            then
                return Fail;
            end if;
            return Pass;
        end Count_Check;


        function Many_Check
            return Test_Result
        is
            function Match_A is new Strombo.Match ('a');
            function Many_0 is new Strombo.Many (Match_A);
            function Many_4 is new Strombo.Many (Match_A, 4);

            Test_Str : String := "aaabbaaaaabaa";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Success, "aaa");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (2, Packrat.Optional_More, "aa");
            Result3 : Slexy.Combinator_Result :=
                Slexy.Create_Result (5, Packrat.Success, "aaaaa");
            Result4 : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Failure, "aaa");
            Result5 : Slexy.Combinator_Result := Slexy.Empty_Fail;
            Result6 : Slexy.Combinator_Result :=
                Slexy.Create_Result (2, Packrat.Needs_More, "aa");
        begin
            if  Many_0 (Test_Str, 1) /= Result1 or Many_4 (Test_Str, 1) /= Result4 or
                Many_4 (Test_Str, 6) /= Result3 or Many_0 (Test_Str, 4) /= Result5 or
                Many_0 (Test_Str, 12) /= Result2 or Many_4 (Test_Str, 12) /= Result6 or
                Many_0 (Test_Str, Test_Str'Last + 5) /= Result5
            then
                return Fail;
            end if;
            return Pass;
        end Many_Check;


        function Many_Until_Check
            return Test_Result
        is
            function Match_A is new Strombo.Match ('a');
            function Many_Until_0 is new Strombo.Many_Until (Match_A, PU.Is_Digit);
            function Many_Until_3 is new Strombo.Many_Until (Match_A, PU.Is_Digit, 3);

            Test_Str : String := "aaaabbaaa123aaa";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (4, Packrat.Failure, "aaaa");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Success, "aaa");
            Result3 : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Optional_More, "aaa");
            Result4 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  Many_Until_0 (Test_Str, 1) /= Result1 or
                Many_Until_0 (Test_Str, 7) /= Result2 or
                Many_Until_3 (Test_Str, 7) /= Result2 or
                Many_Until_3 (Test_Str, 13) /= Result3 or
                Many_Until_0 (Test_Str, 5) /= Result4 or
                Many_Until_0 (Test_Str, Test_Str'Last + 5) /= Result4 or
                Many_Until_3 (Test_Str, Test_Str'Last + 5) /= Result4
            then
                return Fail;
            end if;
            return Pass;
        end Many_Until_Check;


        function Satisfy_Check
            return Test_Result
        is
            function Is_123
                   (Char : in Character)
                return Boolean is
            begin
                return Char = '1' or Char = '2' or Char = '3';
            end Is_123;
            function Is_Abc
                   (Char : in Character)
                return Boolean is
            begin
                return Char = 'a' or Char = 'b' or Char = 'c';
            end Is_Abc;

            function Satisfy_123 is new Strombo.Satisfy (Is_123);
            function Satisfy_Abc is new Strombo.Satisfy (Is_Abc);

            Test_Str : String := "abc123456def";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "b");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "3");
            Result3 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  Satisfy_123 (Test_Str, 6) /= Result2 or
                Satisfy_Abc (Test_Str, 2) /= Result1 or
                Satisfy_Abc (Test_Str, 8) /= Result3 or
                Satisfy_123 (Test_Str, Test_Str'Last + 5) /= Result3
            then
                return Fail;
            end if;
            return Pass;
        end Satisfy_Check;


        function Satisfy_With_Check
            return Test_Result
        is
            function Is_Abc
                   (Char : in Character)
                return Boolean is
            begin
                return Char = 'a' or Char = 'b' or Char = 'c';
            end Is_Abc;
            function Is_123
                   (Char : in Character)
                return Boolean is
            begin
                return Char = '1' or Char = '2' or Char = '3';
            end Is_123;
            function Minus_One
                   (Char : in Character)
                return Character is
            begin
                return Character'Val (Character'Pos (Char) - 1);
            end Minus_One;

            function Satisfy_Bcd is new Strombo.Satisfy_With (Is_Abc, Minus_One);
            function Satisfy_234 is new Strombo.Satisfy_With (Is_123, Minus_One);

            Test_Str : String := "abcde12345";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "c");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "2");
            Result3 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  Satisfy_Bcd (Test_Str, 3) /= Result1 or
                Satisfy_234 (Test_Str, 7) /= Result2 or
                Satisfy_Bcd (Test_Str, 1) /= Result3 or
                Satisfy_234 (Test_Str, Test_Str'Last + 5) /= Result3
            then
                return Fail;
            end if;
            return Pass;
        end Satisfy_With_Check;


        function Match_Check
            return Test_Result
        is
            function Match_A is new Strombo.Match ('a');
            function Match_Slash is new Strombo.Match ('/');
            function Match_4 is new Strombo.Match ('4');

            Test_Str : String := "abc1234./5";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "a");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "/");
            Result3 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "4");
            Result4 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  Match_A (Test_Str, 1) /= Result1 or
                Match_Slash (Test_Str, 9) /= Result2 or
                Match_4 (Test_Str, 7) /= Result3 or
                Match_A (Test_Str, 3) /= Result4 or
                Match_A (Test_Str, Test_Str'Last + 5) /= Result4
            then
                return Fail;
            end if;
            return Pass;
        end Match_Check;


        function Match_With_Check
            return Test_Result
        is
            function Plus_One
                   (Char : in Character)
                return Character is
            begin
                return Character'Val (Character'Pos (Char) + 1);
            end Plus_One;

            function Match_A is new Strombo.Match_With ('b', Plus_One);
            function Match_6 is new Strombo.Match_With ('7', Plus_One);

            Test_Str : String := "abc5678";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "a");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "6");
            Result3 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  Match_A (Test_Str, 1) /= Result1 or
                Match_6 (Test_Str, 5) /= Result2 or
                Match_A (Test_Str, 2) /= Result3 or
                Match_A (Test_Str, Test_Str'Last + 5) /= Result3
            then
                return Fail;
            end if;
            return Pass;
        end Match_With_Check;


        function Multimatch_Check
            return Test_Result
        is
            function Match_String1 is new Strombo.Multimatch ("abc");
            function Match_String2 is new Strombo.Multimatch ("hello");

            Test_Str : String := "abcdefabhelloworldab";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Success, "abc");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (2, Packrat.Needs_More, "ab");
            Result3 : Slexy.Combinator_Result :=
                Slexy.Create_Result (5, Packrat.Success, "hello");
            Result4 : Slexy.Combinator_Result :=
                Slexy.Create_Result (2, Packrat.Failure, "ab");
            Result5 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  Match_String1 (Test_Str, 1) /= Result1 or
                Match_String1 (Test_Str, 7) /= Result4 or
                Match_String2 (Test_Str, 9) /= Result3 or
                Match_String2 (Test_Str, 3) /= Result5 or
                Match_String1 (Test_Str, 19) /= Result2 or
                Match_String1 (Test_Str, Test_Str'Last + 5) /= Result5
            then
                return Fail;
            end if;
            return Pass;
        end Multimatch_Check;


        function Take_Check
            return Test_Result
        is
            function Take_1 is new Strombo.Take;
            function Take_5 is new Strombo.Take (5);

            Test_Str : String := "abcdefghi";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "b");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Needs_More, "ghi");
            Result3 : Slexy.Combinator_Result :=
                Slexy.Create_Result (5, Packrat.Success, "cdefg");
            Result4 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  Take_1 (Test_Str, 2) /= Result1 or Take_5 (Test_Str, 7) /= Result2 or
                Take_5 (Test_Str, 3) /= Result3 or
                Take_1 (Test_Str, Test_Str'Last + 5) /= Result4
            then
                return Fail;
            end if;
            return Pass;
        end Take_Check;


        function Take_While_Check
            return Test_Result
        is
            function Take_Letters is new Strombo.Take_While (PU.Is_Letter);
            function Take_Punch is new Strombo.Take_While (PU.Is_Punctuation);
            function Take_Digits is new Strombo.Take_While (PU.Is_Digit);

            Test_Str : String := "abcde,./;'fghi[]=-^563";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (4, Packrat.Success, "bcde");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (2, Packrat.Success, "hi");
            Result3 : Slexy.Combinator_Result :=
                Slexy.Create_Result (5, Packrat.Success, ",./;'");
            Result4 : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Success, "=-^");
            Result5 : Slexy.Combinator_Result := Slexy.Empty_Fail;
            Result6 : Slexy.Combinator_Result :=
                Slexy.Create_Result (3, Packrat.Optional_More, "563");
        begin
            if  Take_Letters (Test_Str, 2) /= Result1 or
                Take_Letters (Test_Str, 13) /= Result2 or
                Take_Punch (Test_Str, 6) /= Result3 or
                Take_Punch (Test_Str, 17) /= Result4 or
                Take_Letters (Test_Str, 7) /= Result5 or
                Take_Punch (Test_Str, Test_Str'Last + 5) /= Result5 or
                Take_Digits (Test_Str, 20) /= Result6
            then
                return Fail;
            end if;
            return Pass;
        end Take_While_Check;


        function Take_Until_Check
            return Test_Result
        is
            function Take_Till_Punch is new Strombo.Take_Until (PU.Is_Punctuation);
            function Take_Till_Digit is new Strombo.Take_Until (PU.Is_Digit);

            Test_Str : String := "abcde12345;;;fghi67";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (7, Packrat.Success, "de12345");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (4, Packrat.Optional_More, "hi67");
            Result3 : Slexy.Combinator_Result :=
                Slexy.Create_Result (5, Packrat.Success, "abcde");
            Result4 : Slexy.Combinator_Result :=
                Slexy.Create_Result (6, Packrat.Success, ";;fghi");
            Result5 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  Take_Till_Punch (Test_Str, 4) /= Result1 or
                Take_Till_Punch (Test_Str, 16) /= Result2 or
                Take_Till_Digit (Test_Str, 1) /= Result3 or
                Take_Till_Digit (Test_Str, 12) /= Result4 or
                Take_Till_Punch (Test_Str, 11) /= Result5 or
                Take_Till_Punch (Test_Str, Test_Str'Last + 5) /= Result5
            then
                return Fail;
            end if;
            return Pass;
        end Take_Until_Check;


        function Line_End_Check
            return Test_Result
        is
            function LF_End is new Strombo.Line_End (Latin.LF);
            function C_End is new Strombo.Line_End ('c');

            Test_Str : String := "abcd" & Latin.LF & "e";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, (1 => Latin.LF));
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "c");
            Result3 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  LF_End (Test_Str, 5) /= Result1 or C_End (Test_Str, 3) /= Result2 or
                LF_End (Test_Str, Test_Str'Last + 5) /= Result3 or LF_End (Test_Str, 1) /= Result3
            then
                return Fail;
            end if;
            return Pass;
        end Line_End_Check;


        function Input_End_Check
            return Test_Result
        is
            function C_End is new Strombo.Input_End ('c');
            function E_End is new Strombo.Input_End ('e');

            Test_Str : String := "abcde";

            Result1 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "e");
            Result2 : Slexy.Combinator_Result :=
                Slexy.Create_Result (1, Packrat.Success, "c");
            Result3 : Slexy.Combinator_Result := Slexy.Empty_Fail;
        begin
            if  C_End (Test_Str, 3) /= Result2 or E_End (Test_Str, 5) /= Result1 or
                C_End (Test_Str, 6) /= Result3 or E_End (Test_Str, 6) /= Result3 or
                C_End (Test_Str, 1) /= Result3 or E_End (Test_Str, Test_Str'Last + 5) /= Result3
            then
                return Fail;
            end if;
            return Pass;
        end Input_End_Check;


    end Lexer;





    package body Util is


        function In_Set_Check
            return Test_Result
        is
            use type Strmaps.Character_Set;
            Set_1 : Strmaps.Character_Set := Strmaps.To_Set ("abcxyz");
            Set_2 : Strmaps.Character_Set := Strmaps.To_Set ("!""#$");
            function Func_1 is new PU.In_Set (Set_1);
            function Func_2 is new PU.In_Set (Set_2);
        begin
            --  Func_1 testing
            for I in Integer range Character'Pos (Character'First) .. Character'Pos ('a') - 1 loop
                if Func_1 (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range 'a' .. 'c' loop
                if not Func_1 (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('c') + 1 .. Character'Pos ('x') - 1 loop
                if Func_1 (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range 'x' .. 'z' loop
                if not Func_1 (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('z') + 1 .. Character'Pos (Character'Last) loop
                if Func_1 (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            --  Func_2 testing
            for I in Integer range Character'Pos (Character'First) .. Character'Pos ('!') - 1 loop
                if Func_2 (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range '!' .. '$' loop
                if not Func_2 (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('$') + 1 .. Character'Pos (Character'Last) loop
                if Func_2 (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end In_Set_Check;


        function Not_In_Set_Check
            return Test_Result
        is
            use type Strmaps.Character_Set;
            Set_1 : Strmaps.Character_Set := Strmaps.To_Set ("abcxyz");
            Set_2 : Strmaps.Character_Set := Strmaps.To_Set ("!""#$");
            function Func_1 is new PU.Not_In_Set (Set_1);
            function Func_2 is new PU.Not_In_Set (Set_2);
        begin
            --  Func_1 testing
            for I in Integer range Character'Pos (Character'First) .. Character'Pos ('a') - 1 loop
                if not Func_1 (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range 'a' .. 'c' loop
                if Func_1 (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('c') + 1 .. Character'Pos ('x') - 1 loop
                if not Func_1 (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range 'x' .. 'z' loop
                if Func_1 (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('z') + 1 .. Character'Pos (Character'Last) loop
                if not Func_1 (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            --  Func_2 testing
            for I in Integer range Character'Pos (Character'First) .. Character'Pos ('!') - 1 loop
                if not Func_2 (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range '!' .. '$' loop
                if Func_2 (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('$') + 1 .. Character'Pos (Character'Last) loop
                if not Func_2 (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Not_In_Set_Check;





        function Is_Digit_Check
            return Test_Result is
        begin
            for I in Integer range Character'Pos (Character'First) .. Character'Pos ('0') - 1 loop
                if PU.Is_Digit (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range '0' .. '9' loop
                if not PU.Is_Digit (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('9') + 1 .. Character'Pos (Character'Last) loop
                if PU.Is_Digit (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_Digit_Check;


        function Is_Hex_Check
            return Test_Result is
        begin
            for I in Integer range Character'Pos (Character'First) .. Character'Pos ('0') - 1 loop
                if PU.Is_Hex (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range '0' .. '9' loop
                if not PU.Is_Hex (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('9') + 1 .. Character'Pos ('A') - 1 loop
                if PU.Is_Hex (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range 'A' .. 'F' loop
                if not PU.Is_Hex (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('F') + 1 .. Character'Pos ('a') - 1 loop
                if PU.Is_Hex (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range 'a' .. 'f' loop
                if not PU.Is_Hex (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('f') + 1 .. Character'Pos (Character'Last) loop
                if PU.Is_Hex (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_Hex_Check;


        function Is_Letter_Check
            return Test_Result is
        begin
            for I in Integer range Character'Pos (Character'First) .. Character'Pos ('A') - 1 loop
                if PU.Is_Letter (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range 'A' .. 'Z' loop
                if not PU.Is_Letter (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('Z') + 1 .. Character'Pos ('a') - 1 loop
                if PU.Is_Letter (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range 'a' .. 'z' loop
                if not PU.Is_Letter (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('z') + 1 .. Character'Pos (Character'First) loop
                if PU.Is_Letter (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_Letter_Check;


        function Is_Alphanumeric_Check
            return Test_Result is
        begin
            for I in Integer range Character'Pos (Character'First) .. Character'Pos ('0') - 1 loop
                if PU.Is_Alphanumeric (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range '0' .. '9' loop
                if not PU.Is_Alphanumeric (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('9') + 1 .. Character'Pos ('A') - 1 loop
                if PU.Is_Alphanumeric (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range 'A' .. 'Z' loop
                if not PU.Is_Alphanumeric (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('Z') + 1 .. Character'Pos ('a') - 1 loop
                if PU.Is_Alphanumeric (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range 'a' .. 'z' loop
                if not PU.Is_Alphanumeric (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('z') + 1 .. Character'Pos (Character'Last) loop
                if PU.Is_Alphanumeric (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_Alphanumeric_Check;


        function Is_Punctuation_Check
            return Test_Result is
        begin
            for I in Integer range Character'Pos (Character'First) .. Character'Pos ('!') - 1 loop
                if PU.Is_Punctuation (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range '!' .. '/' loop
                if not PU.Is_Punctuation (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('/') + 1 .. Character'Pos (':') - 1 loop
                if PU.Is_Punctuation (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range ':' .. '@' loop
                if not PU.Is_Punctuation (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('@') + 1 .. Character'Pos ('[') - 1 loop
                if PU.Is_Punctuation (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range '[' .. '`' loop
                if not PU.Is_Punctuation (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('`') + 1 .. Character'Pos ('{') - 1 loop
                if PU.Is_Punctuation (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range '{' .. '~' loop
                if not PU.Is_Punctuation (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos ('~') + 1 .. Character'Pos (Character'Last) loop
                if PU.Is_Punctuation (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_Punctuation_Check;


        function Is_ASCII_Check
            return Test_Result is
        begin
            for I in Integer range Character'Pos (Character'First) .. 127 loop
                if not PU.Is_ASCII (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range 128 .. Character'Pos (Character'Last) loop
                if PU.Is_ASCII (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_ASCII_Check;


        function Is_Extended_ASCII_Check
            return Test_Result is
        begin
            for I in Integer range Character'Pos (Character'First) .. 127 loop
                if PU.Is_Extended_ASCII (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range 128 .. Character'Pos (Character'Last) loop
                if not PU.Is_Extended_ASCII (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_Extended_ASCII_Check;


        function Is_Space_Check
            return Test_Result is
        begin
            for I in Integer range Character'Pos (Character'First) .. Character'Pos (' ') - 1 loop
                if PU.Is_Space (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            if not PU.Is_Space (' ') then
                return Fail;
            end if;
            for I in Integer range Character'Pos (' ') + 1 .. Character'Pos (Character'Last) loop
                if PU.Is_Space (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_Space_Check;


        function Is_Linespace_Check
            return Test_Result is
        begin
            for I in Integer range
                Character'Pos (Character'First) .. Character'Pos (Latin.HT) - 1
            loop
                if PU.Is_Linespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            if not PU.Is_Linespace (Latin.HT) then
                return Fail;
            end if;
            for I in Integer range Character'Pos (Latin.HT) + 1 .. Character'Pos (' ') - 1 loop
                if PU.Is_Linespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            if not PU.Is_Linespace (' ') then
                return Fail;
            end if;
            for I in Integer range Character'Pos (' ') + 1 .. Character'Pos (Character'Last) loop
                if PU.Is_Linespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_Linespace_Check;


        function Is_End_Of_Line_Check
            return Test_Result is
        begin
            for I in Integer range
                Character'Pos (Character'First) .. Character'Pos (Latin.LF) - 1
            loop
                if PU.Is_End_Of_Line (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            if not PU.Is_End_Of_Line (Latin.LF) then
                return Fail;
            end if;
            for I in Integer range Character'Pos (Latin.LF) + 1 .. Character'Pos (Latin.CR) - 1 loop
                if PU.Is_End_Of_Line (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            if not PU.Is_End_Of_Line (Latin.CR) then
                return Fail;
            end if;
            for I in Integer range
                Character'Pos (Latin.CR) + 1 .. Character'Pos (Character'Last)
            loop
                if PU.Is_End_Of_Line (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_End_Of_Line_Check;


        function Is_Whitespace_Check
            return Test_Result is
        begin
            for I in Integer range
                Character'Pos (Character'First) .. Character'Pos (Latin.HT) - 1
            loop
                if PU.Is_Whitespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range Latin.HT .. Latin.LF loop
                if not PU.Is_Whitespace (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos (Latin.LF) + 1 .. Character'Pos (Latin.CR) - 1 loop
                if PU.Is_Whitespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            if not PU.Is_Whitespace (Latin.CR) then
                return Fail;
            end if;
            for I in Integer range Character'Pos (Latin.CR) + 1 .. Character'Pos (' ') - 1 loop
                if PU.Is_Whitespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            if not PU.Is_Whitespace (' ') then
                return Fail;
            end if;
            for I in Integer range Character'Pos (' ') + 1 .. Character'Pos (Character'Last) loop
                if PU.Is_Whitespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Is_Whitespace_Check;


        function Not_Whitespace_Check
            return Test_Result is
        begin
            for I in Integer range
                Character'Pos (Character'First) .. Character'Pos (Latin.HT) - 1
            loop
                if not PU.Not_Whitespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            for C in Character range Latin.HT .. Latin.LF loop
                if PU.Not_Whitespace (C) then
                    return Fail;
                end if;
            end loop;
            for I in Integer range Character'Pos (Latin.LF) + 1 .. Character'Pos (Latin.CR) - 1 loop
                if not PU.Not_Whitespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            if PU.Not_Whitespace (Latin.CR) then
                return Fail;
            end if;
            for I in Integer range Character'Pos (Latin.CR) + 1 .. Character'Pos (' ') - 1 loop
                if not PU.Not_Whitespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            if PU.Not_Whitespace (' ') then
                return Fail;
            end if;
            for I in Integer range Character'Pos (' ') + 1 .. Character'Pos (Character'Last) loop
                if not PU.Not_Whitespace (Character'Val (I)) then
                    return Fail;
                end if;
            end loop;
            return Pass;
        end Not_Whitespace_Check;


    end Util;


end Ratnest.Tests;